오토핫키] 구이 버튼에 마우스를 가져다 놓으면 버튼에 대한 추가 설명을 띄우는 방법

압살맨 오픈채팅 바로가기

---

압살맨 유튜브 바로가기

---

질문

안녕하세요 오토핫키에 재미를 들이이고있는중인데 만들다보니 궁금증이 생겨서 고수님들의 도움을 한번 청해봅니다

​

구이버튼마다 마우스포인트를 가져다놓으면 엑셀처럼 버튼에대한 설명 메모를 추가할수있는 방법이있을까요?

​

혼자 사용할땐 필요가없지만 공유를할때 어느기능이있는지 추가 정보를 기입하면 좋을꺼같은 생각에 글올려봅니다.

​

고수님들 도움주시면 감사하겠습니다

---

답변

해당 질문에 대한 답변은 OnMessage 를 통해 해결할 수 있다.

OnMessage 는 스크립트가 지정된 메시지를 받을 때 자동으로 호출할 함수 또는 함수 객체를 지정한다.

OnMessage(MsgNumber [, Function, MaxThreads])

여기서 MsgNumber 는 우리가 PostMessage 에서 비활성으로 키를 입력하거나 혹은 마우스를 클릭하는 동작을 구현할 때

사용하는 Msg 로 WM_MouseMove := 0x0200 같은 형태이다.

 

 

 

여기서 질문에 대한 답변은

Gui, Show

 

이후에

ListTool := {"Btn_Enter" : "확인버튼"
           , "Btn_Exit" : "종료버튼"}

OnMessage(0x200, "ShowHelp")

을 추가한다. 여기서 ListTool 이란 연관배열은 Gui 에 각 Control 에 지정한 {vLabel : ToolTip} 을 띄울 내용 을 적는 것이다.

 

이후 함수 하나를 추가해주면 끝이다.

ShowHelp() {
    Global ListTool
    Static Current := 0
    if(A_GuiControl <> Current)
        ToolTip, % ListTool[(Current := A_GuiControl)]
    return
}

 

Gui, Margin, 10, 10
Gui, Add, Button, x10 y10 w200 h20 vBtn_Enter gEnter, 확인
Gui, Add, Button, x10 y40 w200 h20 vBtn_Exit gGuiClose, 종료
Gui, Show

ListTool := {"Btn_Enter" : "확인버튼"
           , "Btn_Exit" : "종료버튼"}
OnMessage(0x200, "ShowHelp")
return

Enter:
Msgbox, 확인
return

GuiClose:
ExitApp

ShowHelp() {
    Global ListTool
    Static Current := 0
    if(A_GuiControl <> Current)
        ToolTip, % ListTool[(Current := A_GuiControl)]
    return
}

이것이 예시가 될 수 있을 것이다.